Что-то случилось с цветоком. Как быть?

[Mr.Kubikus]

У нас в офисе есть цветок. Стоит на подоконнике и радует (радовал) нас своими зелеными листиками. Несколько дней назад часть листиков пожелтела и еще часть опала. После небольшого расследования удалось выяснить, что за три дня его полили сразу три человека. То есть налицо несогласованность действий, повышенный расход воды, переувлажнение почвы и как следствие пожелтение листиков.

Поэтому есть вопрос: а можно ли как-то автоматизировать процесс полива и защитить цветочек от подобных ситуаций?

Буду рад вашим советам.

Картинка для привлечения внимания:

project-flower-1.jpg (140.66 КБ) 41616 просмотров

[Mr.Kubikus]

Идея №1

Надо каким-либо способом измерять влажность почвы и в зависимости от результата сигнализировать о необходимости полить цветок. Тогда можно будет избежать пересушивания или наоборот чрезмерного увлажнения почвы.

Реализация

Тадам! Оказывается уже есть специальный датчик для измерения влажности почвы. Он так и называется - Датчик влажности почвы. Его артикул SEN0114.

project-flower-10.JPG (97.69 КБ) 41614 просмотров

Принципиальная схема датчика:

project-flower-19.JPG (15.97 КБ) 41614 просмотров

Остается подцепить его к Ардуине и написать программу, выполняющую действия,описанные в Идеи №1

[Mr.Kubikus]

Разделим решение этой задачи на несколько этапов:

1. Исследованние
2. Разработка
3. Испытания

Исследование

На этом этапе нам надо будет собрать и проанализировать информацию о характере изменения сигнала от датчика влажности. Для этого сделаем простой макет, который будет принимать сигнал от датчика и сохранять его для последующего анализа. Доступ к накопленным данным должен осуществляться через веб-интерейс. Т.е. через браузер.

Для хранения и отображения зарегистрированных значений будем использовать COSM - web-сервис с HTTP API для регистрации и визуализации информации от любых датчиков. Передача информации от датчиков осуществляется путем http запросов к серверу cosm.com. Отправлять будем нормированное значение, полученное по формуле SensorValue = 100 * ADCResult / 1023.

Железки которые понадобятся на этом этапе:

• Датчик влажности почвы
• Arduino Uno R3
• Ethernet Shield
• IO Expansion Shiled (не обязательно)

Собираем схему и идем регистрироваться на сайт http://cosm.com. После регистрации на COSMе можно создать проект регистрации данных. В одном проекте может быть несколько потоков данных. Нам пока нужен только один поток для датчика влажности почвы.

Вот что у меня получилось - https://cosm.com/feeds/71140.

А это "живая" картинка с сервера, которая генерируется динамически:

Обратите внимание на URL этой картинки.

Теперь понаблюдаем несколько дней за поведением сигнала от датчика. Цветок поливать не будем.

[Mr.Kubikus]

Пошел второй день эксперимента. Пока влажность держится на отметке 73-75% и упорно не желает снижаться. Продолжаем наблюдать.

[Mr.Kubikus]

Прошло уже четыре дня. Теперь на недельном графике хорошо видно, что влажность постепенно снижается. Подождем еще пару дней и будем переходить ко второму этапу - Разработка.

[Mr.Kubikus]

Ну вот, влажность упала до 44% и у цветка начали скукоживаться листики. Кажется пришло время полить цветочек. Зальем воды и понаблюдаем за изменениями на графике.

[mikbo]

Здравствуйте!
Очень интересный опыт!
А нельзя ли еще и исходные тексты опубликовать?

[Mr.Kubikus]

Привет!

Исходники обязательно опубликую. Проект еще не закончен. Сейчас мы заканчиваем исследования и переходим в разработке системы управления. По ходу работы буду выкладывать материалы.

Не переключайтесь.

[mikbo]

Ну с системой управления все более-менее понятно.
Интерсна именно COSM - часть...

[Mr.Kubikus]

Ок. Выкладываю скетч, который сейчас используется для работы с COSM.COM:

Код: Выделить всё

/*

 Cosm sensor client by http://PACPAC.RU
 
 This sketch connects moisture analog sensor to Cosm (http://www.cosm.com)
 using a Wiznet Ethernet shield.
 
 Originated from: 
 http://arduino.cc/en/Tutorial/PachubeClient 

*/

#include <SPI.h>
#include <Ethernet.h>

#define APIKEY         "XXX" // COSM API key
#define FEEDID         71140 // your feed ID
#define USERAGENT      " Project Flower (71140)" // User agent is the project name

// Assign a MAC address for the ethernet controller.
byte mac[] = { 0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED};

// Fill in an available IP address on your network here,
// for manual configuration:
IPAddress ip(192,168,0,11);
// initialize the library instance:
EthernetClient client;

// If you don't want to use DNS (and reduce your sketch size)
// use the numeric IP instead of the name for the server:
IPAddress server(216,52,233,121);      // numeric IP for api.cosm.com
//char server[] = "api.cosm.com";   // name address for cosm API

unsigned long lastConnectionTime = 0;          // last time you connected to the server, in milliseconds
boolean lastConnected = false;                 // state of the connection last time through the main loop
const unsigned long postingInterval = 10*1000; // delay between updates to Cosm.com

void setup() {
  // start serial port:
  Serial.begin(9600);
 // start the Ethernet connection:
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    // DHCP failed, so use a fixed IP address:
    Ethernet.begin(mac, ip);
  }
}

void loop() {
  // read the analog sensor:
  int sensorReading = (int) 100.0 * (analogRead(A0)/ 1023.0);   

  // if there's incoming data from the net connection.
  // send it out the serial port.  This is for debugging
  // purposes only:
  if (client.available()) {
    char c = client.read();
    Serial.print(c);
  }

  // if there's no net connection, but there was one last time
  // through the loop, then stop the client:
  if (!client.connected() && lastConnected) {
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
  }

  // if you're not connected, and ten seconds have passed since
  // your last connection, then connect again and send data:
  if(!client.connected() && (millis() - lastConnectionTime > postingInterval)) {
    sendData(sensorReading);
  }
  // store the state of the connection for next time through
  // the loop:
  lastConnected = client.connected();
}

// this method makes a HTTP connection to the server:
void sendData(int thisData) {
  // if there's a successful connection:
  if (client.connect(server, 80)) {
    Serial.print("Sensor value = ");
    Serial.println(thisData);
    
    Serial.println("connecting...");
    
    // send the HTTP PUT request:
    client.print("PUT /v2/feeds/");
    client.print(FEEDID);
    client.println(".csv HTTP/1.1");
    client.println("Host: api.cosm.com");
    client.print("X-ApiKey: ");
    client.println(APIKEY);
    client.print("User-Agent: ");
    client.println(USERAGENT);
    client.print("Content-Length: ");

    // calculate the length of the sensor reading in bytes:
    // 8 bytes for "sensor1," + number of digits of the data:
    int thisLength = 4 + getLength(thisData);
    client.println(thisLength);

    // last pieces of the HTTP PUT request:
    client.println("Content-Type: text/csv");
    client.println("Connection: close");
    client.println();

    // here's the actual content of the PUT request:
    client.print("M01,");
    client.println(thisData);
  
  } 
  else {
    // if you couldn't make a connection:
    Serial.println("connection failed");
    Serial.println();
    Serial.println("disconnecting.");
    client.stop();
  }
   // note the time that the connection was made or attempted:
  lastConnectionTime = millis();
}


// This method calculates the number of digits in the
// sensor reading.  Since each digit of the ASCII decimal
// representation is a byte, the number of digits equals
// the number of bytes:

int getLength(int someValue) {
  // there's at least one byte:
  int digits = 1;
  // continually divide the value by ten, 
  // adding one to the digit count for each
  // time you divide, until you're at 0:
  int dividend = someValue /10;
  while (dividend > 0) {
    dividend = dividend /10;
    digits++;
  }
  // return the number of digits:
  return digits;
}

В строке #define APIKEY используйте ваш ключ вместо XXX.